Traducciones de esta página:

Herramientas de usuario

Herramientas del sitio


es:escarabajo

ESCARABAJO

Ficha

Escarabajo_p1.jpg

Autor ?????????????
Compatibilidad Amstrad PCW 8256 / 8512 / 9512
Año ????
Género Arcade
Controles Teclado
Idioma Español
Estado Preservado

Capturas

Escarabajo_screenshot01.png Escarabajo_screenshot02.png Escarabajo_screenshot03.png Escarabajo_screenshot04.png

Descripción

Escarabajo es un juego divertido que no brilla por su nivel gráfico, pudiéndose mejorar los mismos y con algo de sonido.

Nuestra misión del juego trata de un personaje simpático, un escarabajo que ha de ir por un laberinto comiendo frutas y huyendo de una bota que nos hace el juego imposible. Tendremos que tener mucho cuidado con las paredes ya que estas están electrificadas y perderemos una vida y ojo con lo que cojamos que existen minas explosivas.

Comenzamos el juego con tres vidas y un total de 10 fases. Una vez que huyamos por el laberinto de la perseguidora bota y nos comamos las piezas de frutas que se encuentran en el mismo, se nos abrirá una puerta para que podamos pasar de fase.

Listado

  • Listado - ESCARAB.BAS
1  PRINT CHR$(27)+"f"
10 cl$=CHR$(27)+"E"+CHR$(27)+"H"
20 DEF FN at$(x,y,t$)=CHR$(27)+"Y"+CHR$(32+y)+CHR$(32+x)+t$
30 PRINT cl$
90 GOSUB 1970
100 PRINT cl$:a=11:d=9:m=14:li=3:u=1:q=1:DIM e(120)
110 GOSUB 960:GOSUB 920:GOSUB 760:GOSUB 1210
120 m1$=q3$
130 m2$=q4$
140 RESTORE
145 u=1:q=1
150 FOR n=1 TO 15
155 a$=INKEY$
160 IF a$="q" OR a$="Q" THEN GOSUB 290
170 IF a$="a" OR a$="A" THEN GOSUB 340
180 IF a$="o" OR a$="O" THEN GOSUB 390
190 IF a$="p" OR a$="P" THEN GOSUB 440
200 PRINT FN at$(u,q,"");
201 PRINT "  ":PRINT FN at$(u,q+1,"");
202 PRINT "  ":IF u=a AND d=q THEN GOSUB 610
210 READ u,q
230 PRINT FN at$(u,q,"");
231 PRINT q15$:PRINT FN at$(u,q+1,"");
232 PRINT q16$
240 IF u=a AND d=q THEN GOSUB 610
250 NEXT n
260 nki=nki+1:IF nki/2=nki/2 THEN RESTORE
270 GOTO 150
280 ' ************ ARRIBA *************
290 PRINT FN at$(a,d,"  "):PRINT FN at$(a,d+1,"  ")  
300 m=m-12:d=d-2
310 GOSUB 690
320 RETURN
330 ' ************ ABAJO  *************
340 PRINT FN at$(a,d,"  "):PRINT FN at$(a,d+1,"  ")
350 m=m+12:d=d+2
360 GOSUB 690
370 RETURN
380 ' ************ IZQUIERDA **********
390 PRINT FN at$(a,d,"  "):PRINT FN at$(a,d+1,"  ")
400 m=m-1:a=a-2
410 GOSUB 690
420 RETURN
430 ' ************ DERECHA   **********
440 PRINT FN at$(a,d,"  "):PRINT FN at$(a,d+1,"  ")
450 m=m+1:a=a+2
460 GOSUB 690
470 RETURN
600 ' ********* PIERDE VIDA *********** 
610 li=li-1:po=po+3
615 PRINT CHR$(7)
630 PRINT FN at$(3,8+po,"");
631 PRINT q7$:PRINT FN at$(3,9+po,"");
632 PRINT q8$
640 FOR i=1 TO 2000:NEXT i
650 IF li=0 THEN GOSUB 840
660 PRINT FN at$(u,q,"  "):PRINT FN at$(u,q+1,"  ")
670 a=11:d=9:m=14:u=1:q=1:PRINT FN at$(a,d,"");
671 PRINT q3$:PRINT FN at$(a,d+1,"");
672 PRINT q4$:GOTO 120
680 ' ****** COMPRUEBA CHOQUE *********
690 IF man>=3 AND m=96 THEN IF man>3 THEN uno=uno+1:GOSUB 820 ELSE GOSUB 820
700 IF e(m)=0 THEN PRINT CHR$(7):GOSUB 610
710 IF e(m)=2 THEN PRINT CHR$(7):ta=ta+100:man=man+1:e(m)=1:IF man=3 THEN PRINT FN at$(31,21,"  "):PRINT FN at$(31,22,"  "):GOSUB 7000
730 PRINT FN at$(a,d,"");
731 PRINT m1$:PRINT FN at$(a,d+1,"");
732 PRINT m2$
740 RETURN
750 ' ****** MUESTRA VIDAS ************
760 PRINT FN at$(2,8,"VIDAS"):l=8
770 FOR n=1 TO 3
780 l=l+3:PRINT FN at$(3,l,q3$):PRINT FN at$(3,l+1,q4$)
790 NEXT
800 RETURN
810 ' ****** cambio de pantalla *******
819 IF ida=11 THEN GOTO 2180
820 ON ida GOTO 1260,1310,1360,1420,1470,1520,1570,1630,1750,2180
840 ' ********* FINAL *****************
845 PRINT cl$
860 GOSUB 960:PRINT FN at$(19,20,q13$):PRINT FN at$(19,21,q14$):PRINT FN at$(1,2,"   Ohhhhhh!!!!!!!!    LO SIENTO!!!!!!!")
870 FOR x=1 TO 20:PRINT FN at$(19,x,q17$):PRINT FN at$(19,x+1,q16$):FOR r=1 TO 10:NEXT r:NEXT x
880 FOR n=1 TO 1000:NEXT
890 PRINT FN at$(6,23,"PULSA S PARA JUGAR OTRA VEZ O N PARA ACABAR")
900 b$=INKEY$:IF b$="n" OR b$="N" THEN GOTO 10000
901 b$=INKEY$:IF b$="s" OR b$="S" THEN RUN ELSE GOTO 900
910 ' ******** DIBUJA PANTALLA  *******
920 FOR n=9 TO 32:PRINT FN at$(n,7,CHR$(143)):PRINT FN at$(n,8,CHR$(143)):PRINT FN at$(n,23,CHR$(143)):PRINT FN at$(n,24,CHR$(143)):NEXT
930 FOR n=9 TO 22:PRINT FN at$(9,n,q18$):PRINT FN at$(31,n,q18$):NEXT
940 RETURN
950 ' ******** VARIABLES **************
960 q1$=CHR$(164)+CHR$(164):q2$=CHR$(164)+CHR$(164):q3$=CHR$(172)+CHR$(188):q4$=CHR$(172)+CHR$(188):q5$=CHR$(210)+CHR$(212):q6$=CHR$(211)+CHR$(213):q7$=CHR$(166)+CHR$(166):q8$=CHR$(166)+CHR$(166):q9$=CHR$(93)+CHR$(63):q10$=CHR$(93)+CHR$(63)
970 q11$=CHR$(143)+CHR$(143):q12$=CHR$(143)+CHR$(143):q13$=CHR$(172)+CHR$(188):q14$=CHR$(172)+CHR$(188):q15$=" "+CHR$(249):q16$=CHR$(188)+CHR$(188):q17$=" "+CHR$(249):q18$=CHR$(143)+CHR$(143)
980 RETURN
990 ' ******* SUBRUTINA PANTALLA ******
1000 GOSUB 920:FOR i=1 TO 110:e(i)=1:NEXT
1010 FOR i=1 TO 108 STEP 12:e(i)=0:e(i-1)=0:NEXT
1020 FOR i=1 TO 12:e(i)=0:e(1+96)=0:NEXT
1030 PRINT FN at$(31,21,q18$):PRINT FN at$(31,22,q18$)
1040 FOR j=1 TO 14:PRINT FN at$(11,8+j,SPACE$(20)):NEXT j
1050 RESTORE:FOR n=1 TO da1:READ o,p:NEXT
1060 FOR e=1 TO du:READ h,p
1070 PRINT FN at$(h,p,"");
1071 PRINT q11$:PRINT FN at$(h,p+1,"");
1072 PRINT q12$
1080 NEXT e
1100 FOR n=1 TO 3
1110 READ j,k:PRINT FN at$(j,k,"");
1111 PRINT q9$:PRINT FN at$(j,k+1,"");
1112 PRINT q10$
1120 NEXT
1130 PRINT FN at$(11,3,"FASE NUMERO:");
1131 PRINT pan
1140 PRINT FN at$(7,5,"MISION: SALIR CON LLAVES");
1141 PRINT q$
1150 PRINT FN at$(a,d,q3$):PRINT FN at$(a,d+1,q4$)
1160 PRINT FN at$(34,7,"TANTEO")
1170 man=0:q=1:u=1
1180 IF ro=4 THEN READ i,s:PRINT FN at$(i,s,q1$):PRINT FN at$(i,s+1,q2$)
1190 RETURN
1200 ' ****** PRIMERA PANTALLA ********
1210 pan=1:ida=1:da1=30:du=15
1220 GOSUB 1000
1230 e(18)=0:e(27)=0:e(33)=0:e(40)=0:e(41)=0:e(45)=0:e(52)=0:e(53)=0:e(59)=0:e(64)=0:e(67)=0:e(70)=0:e(88)=0:e(91)=0:e(79)=0:e(23)=2:e(43)=2:e(86)=2
1240 RETURN
1250 ' ******** SEGUNDA PANTALLA **********
1260 a=11:d=9:m=14:man=8:ida=2:pan=2:da1=47:du=17
1270 GOSUB 1000
1280 e(15)=0:e(28)=0:e(27)=0:e(35)=0:e(40)=0:e(41)=0:e(45)=0:e(52)=0:e(53)=0:e(68)=0:e(71)=0:e(78)=0:e(86)=0:e(87)=0:e(94)=0:e(17)=0:e(23)=2:e(28)=2:e(94)=2
1290 GOTO 120
1300 ' ******* TERCERA PANTALLA *********
1310 pan=3:ida=3:da1=68:du=21:a=11:d=9:m=14:man=0
1320 GOSUB 1000
1330 e(15)=0:e(18)=0:e(23)=0:e(27)=0:e(28)=0:e(33)=0:e(39)=0:e(41)=0:e(45)=0:e(53)=0:e(70)=0:e(71)=0:e(74)=0:e(75)=0:e(78)=0:e(81)=0:e(86)=0:e(87)=0:e(89)=0:e(90)=0:e(91)=0:e(40)=2:e(17)=2:e(83)=2
1340 GOTO 120
1350 ' ******* CUARTA PANTALLA **********
1360 pan=4:ida=4:da1=91:du=26:a=11:d=9:m=14:man=0:ro=4:x1=15:y1=21:x2=88
1370 GOSUB 1000
1380 e(18)=0:e(20)=0:e(22)=0:e(23)=0:e(27)=0:e(28)=0:e(35)=0:e(45)=0:e(50)=0:e(52)=0:e(57)=0:e(59)=0:e(62)=0:e(67)=0:e(70)=0:e(71)=0:e(74)=0:e(75)=0
1390 e(78)=0:e(81)=0:e(86)=0:e(87)=2:e(90)=0:e(91)=0:e(88)=0:e(19)=0:e(46)=2:e(83)=2:e(89)=2
1400 GOTO 120
1410 ' ***** QUINTA PANTALLA *****
1420 pan=5:ida=5:da1=121:du=23:a=11:d=9:m=14:man=0:ro=0
1430 GOSUB 1000
1440 e(15)=0:e(18)=0:e(22)=0:e(23)=0:e(27)=0:e(41)=0:e(43)=0:e(45)=0:e(58)=0:e(59)=0:e(62)=0:e(64)=0:e(66)=0:e(68)=0:e(70)=0:e(71)=0:e(75)=0:e(78)=0:e(79)=0:e(83)=0:e(89)=0:e(90)=0:e(91)=0:e(17)=2:e(74)=2:e(92)=2
1450 GOTO 120
1460 ' ***** SEXTA PANTALLA *****
1470 pan=6:ida=6:da1=147:a=11:d=9:man=0:ro=4:du=20:x1=11:y1=19:x2=74:m=14
1480 GOSUB 1000
1490 e(18)=0:e(22)=0:e(27)=0:e(28)=0:e(33)=0:e(39)=0:e(41)=0:e(46)=0:e(50)=0:e(66)=0:e(67)=0:e(67)=0:e(70)=0:e(71)=0:e(74)=0:e(75)=0:e(77)=0:e(87)=0:e(88)=0:e(91)=0:e(92)=0:e(23)=2:e(62)=2:e(89)=2:e(86)=2
1500 GOTO 120
1510 ' ****** SEPTIMA PANTALLA ****
1520 pan=7:ida=7:da1=171:a=11:d=9:man=0:ro=0:du=22:m=14
1530 GOSUB 1000
1540 e(19)=0:e(23)=0:e(27)=0:e(28)=0:e(33)=0:e(39)=0:e(41)=0:e(43)=0:e(45)=0:e(46)=0:e(53)=0:e(57)=0:e(64)=0:e(67)=0:e(68)=0:e(70)=0:e(71)=0:e(74)=0:e(75)=0:e(79)=0:e(94)=2:e(40)=2:e(59)=2:e(86)=2
1550 GOTO 120
1560 ' ********* OCTAVA PANTALLA ***********
1570 pan=8:ida=8:da1=196:a=11:d=9:man=0:ro=4:du=24:m=14:x1=11:y1=17:x2=62
1580 GOSUB 1000
1590 e(15)=0:e(18)=0:e(22)=0:e(27)=0:e(28)=0:e(33)=0:e(39)=0:e(41)=0:e(42)=0:e(43)=0:e(46)=0:e(53)=0:e(57)=0:e(62)=0:e(66)=0:e(67)=0:e(71)=0:e(75)=0:e(79)=0:e(86)=0
1600 e(87)=0:e(88)=0:e(89)=0:e(94)=0:e(17)=2:e(40)=2:e(23)=2:e(74)=2
1610 GOTO 120
1620 ' ******* NOVENA PANTALLA *********
1630 pan=9:ida=9:da1=224:a=11:d=9:man=0:ro=0:du=25:m=14
1640 FOR j=1 TO 14:PRINT FN at$(11,8+j,SPACE$(20)):NEXT j
1650 PRINT FN at$(15,12,"FASE OSCURA")
1660 PRINT FN at$(14,14,"  BOMBILLAS:");
1661 PRINT uno
1670 IF uno=3 THEN at$(17,17,"HAY LUZ"):GOTO 1690
1680 PRINT FN at$(16,17,"NO HAY LUZ"):q11$="  ":q12$="  "
1690 FOR j=1 TO 2500:NEXT j
1700 GOSUB 1000
1710 e(18)=0:e(19)=0:e(22)=0:e(27)=0:e(28)=0:e(33)=0:e(40)=0:e(42)=0:e(43)=0:e(44)=0:e(46)=0:e(62)=0:e(66)=0:e(67)=0:e(71)=0:e(74)=0:e(75)=0:e(78)=0:e(79)=0:e(86)=0:e(87)=0:e(88)=0:e(89)=0
1720 e(90)=0:e(91)=0:e(94)=0:e(20)=2:e(23)=2:e(89)=2
1730 GOTO 120
1740 ' ********** DECIMA PANTALLA **********
1750 GOSUB 960
1760 pan=10:ida=10:da1=252:a=11:d=9:man=0:ro=0:du=28:m=14:q9$="  ":q10$="''"
1770 GOSUB 1000
1780 e(15)=0:e(17)=0:e(19)=0:e(20)=0:e(27)=0:e(33)=0:e(35)=0:e(39)=0:e(41)=0:e(42)=0:e(44)=0:e(45)=0:e(53)=0:e(57)=0:e(59)=0:e(62)=0:e(64)=0:e(67)=0:e(71)=0:e(75)=0
1790 e(77)=0:e(79)=0:e(81)=0:e(86)=0:e(91)=0:e(92)=0:e(94)=0:e(83)=2:e(23)=2:e(87)=2
1800 GOTO 120
1810 ' **** DATAS ****
1820 DATA 29,21,27,19,25,21,23,19,25,17,23,15,21,15,19,15,17,17,15,19,13,17,13,15,11,13,11,11,11,9
1830 DATA 29,21,29,21,27,19,25,21,23,19,25,17,27,15,29,13,27,11,25,9,23,11,21,11,19,11,17,11,15,9
1840 DATA 19,9,13,11,25,11,15,13,17,13,25,13,15,15,17,15,29,15,15,17,21,17,27,17,21,19,15,21,21,21,29,9,21,13,11,21
1850 DATA 13,9,17,9,23,9,13,11,29,11,15,13,17,13,25,13,15,15,17,15,23,17,29,17,19,19,11,21,13,21,23,21,27,21,29,9,15,11,15,21
1860 DATA 13,9,19,9,29,9,13,11,15,11,25,11,13,13,17,13,25,13,17,15,27,17,29,17,11,19,13,19,19,19,25,19,11,21,13,21,17,21,19,21,21,21,17,9,15,13,29,19
1870 DATA 19,9,21,9,23,9,27,9,29,9,13,11,15,11,29,11,25,13,11,15,15,15,25,15,29,15,11,17,21,17,27,17,29,17,11,19,13,19,19,19,25,19,11,21,15,21,19,21,21,21,17,21,27,13,29,19,13,21
1880 DATA 13,9,19,9,27,9,29,9,13,11,17,13,21,13,25,13,11,15,27,15,29,15,11,17,15,17,19,17,23,17,27,17,29,17,13,19,19,19,21,19,29,19,17,21,19,21,23,21,11,19,17,9,23,21
1890 DATA 19,9,27,9,13,11,15,11,25,11,13,13,17,13,27,13,11,15,19,17,21,17,27,17,29,17,11,19,13,19,17,19,13,21,15,21,21,21,17,21,11,17,29,9,15,13,11,21
1900 DATA 21,9,29,9,13,11,15,11,25,11,13,13,17,13,21,13,25,13,27,13,17,15,25,15,15,17,21,17,23,17,27,17,29,17,11,19,13,19,21,19,17,21,27,21,15,13,29,15,11,21
1910 DATA 13,9,19,9,27,9,13,11,15,11,25,11,13,13,17,13,19,13,21,13,27,13,17,15,25,15,11,17,19,17,21,17,29,17,13,19,21,19,27,21,13,21,15,21,17,21,15,13,17,9,29,9,11,19,15,13
1920 DATA 19,9,21,9,27,9,13,11,15,11,25,11,15,13,19,13,21,13,23,13,27,13,11,17,19,17,21,17,29,17,11,19,13,19,19,19,21,19,11,21,13,21,15,21,19,21,21,21,27,21,23,9,29,9,17,21
1930 DATA 13,9,17,9,19,9,21,9,23,9,13,11,25,11,29,11,13,13,17,13,19,13,23,13,25,13,17,15,25,15,29,15,11,17,15,17,21,17,19,17,13,19,17,19,21,19,25,19,11,21,21,21,23,21,27,21,29,9,13,21,29,19,11,19
1940 ' ***** BOMBILLAS *****
1950 PRINT FN at$(x1,y1,"  "):PRINT FN at$(x1,y1+1,"  "):e(x2)=1
1960 RETURN
1970 ' ****** INSTRUCCIONES *******
1980 PRINT FN at$(13,3,"I N S T R U C C I O N E S")
1990 PRINT:PRINT "Este es un divertido juego en el cual tu mision consiste en atravesar el laberinto de 10 fases."
2000 PRINT:PRINT " Ten cuidado  ya que las paredes estan electrizadas, encontraras minas explosivas, no  las toques, tambien hay una molesta bota que te estara pisando los talones."
2010 PRINT:PRINT " Para pasar de una  fase a otra debes comerte  todas las  frutas que encuentres en la fase donde estes."
2020 PRINT:PRINT "Las teclas para mover el escarabajo son:  Q:Arriba  A:Abajo  O:Izquierda   P:derecha"
2030 PRINT:PRINT "PULSA UNA TECLA PARA EMPEZAR"
2040 WHILE INKEY$="":WEND
2050 RETURN
2170 ' ********* TERMINAR ***********
2180 PRINT cl$:GOSUB 960:FOR n=1 TO 40 STEP 2:PRINT FN at$(n,2,"");
2181 PRINT q11$:PRINT FN at$(n,3,"");
2182 PRINT q12$:PRINT FN at$(n,22,"");
2183 PRINT q11$:PRINT FN at$(n,23,"");
2184 PRINT q12$:NEXT n
2190 FOR n=1 TO 22:PRINT FN at$(1,n+1,q11$):PRINT FN at$(1,n+2,q12$):PRINT FN at$(39,n+1,q12$):NEXT n
2200 PRINT FN at$(3,13,"ENHORABUENA!!!! LO CONSEGUISTES !!!")
2210 FOR i=1 TO 4
2220 FOR n=10 TO 30 STEP 2:PRINT FN at$(n,10,q3$):PRINT FN at$(n,11,q4$):PRINT FN at$(n,15,q3$):PRINT FN at$(n,16,q4$):FOR rt=1 TO 30:NEXT rt:PRINT FN at$(n,10,"  "):PRINT FN at$(n,11,"  "):PRINT FN at$(n,15,"  "):PRINT FN at$(n,16,"  "):NEXT n
2240 NEXT i
2250 PRINT FN at$(13,18,"PULSA LA TECLA A"):PRINT FN at$(5,20,"PARA JUGAR OTRA VEZ")
2260 c$=INKEY$:IF c$="A" OR c$="a" THEN RUN ELSE GOTO 2250
7000 PRINT FN at$(34,9,"");
7010 PRINT ta
7030 RETURN
10000 PRINT cl$:PRINT FN at$(9,15,"*****************************   ADIOS   *****************************"):FOR a=1 TO 2000:NEXT a:END

Controles

      Q = ARRIBA 
      A = ABAJO
      O = IZQUIERDA
      P = DERECHA 

Carga del programa

1.- Introducir el disco CP/M por la cara 2
2.- Escribir BASIC y esperar a que cargue
3.- Retirar el disco CP/M e introducir el disco que contiene el juego Escarabajo
4.- Teclear run "Escarab" y pulsar la tecla "ENTER"

Extras

Descarga

  • Escarabajo (juego en formato dsk, comprimido con zip)

Enlaces

es/escarabajo.txt · Última modificación: 2017/02/01 13:09 por jevicac