User Tools

Site Tools





en:master_mind_espanol

Differences

This shows you the differences between two versions of the page.

Link to this comparison view

en:master_mind_espanol [2022/06/30 13:33] (current)
jevicac created
Line 1: Line 1:
 +====== MASTER-MIND ======
 +
 +{{:otros:Master_mind_sp_p1.jpg?690|}}
 +
 +===== Info =====
 +^ Author | Gustavo Ernesto García Pérez |
 +^ Computer | Amstrad PCW 8256 / 8512 / 9512 |
 +^ Year | 1988 |
 +^ Gender | Board |
 +^ Controls | Keyboard |
 +^ Languages | Spanish |
 +^ State | [[preserved|Preserved]] |
 +
 +===== Screenshots =====
 +
 +{{:otros:Master_Mind_sp_screenshot01.png?220}} {{:otros:Master_Mind_sp_screenshot02.png?220}} {{:otros:Master_Mind_sp_screenshot03.png?220}} {{:otros:Master_Mind_sp_screenshot04.png?220}}
 +
 +===== Description =====
 +
 +MASTER MIND is precisely a board game. It was considered some time ago in the UK as the best game of the year.
 +
 +You don't need a joystick to play, just logic and strategy. One thing that needs to be mentioned is that since the PCW does not have a color monitor, the colors of the pins have had to be simulated with different green screen densities. At first this circumstance can cause some confusion because the "color" of the pegs is not very well distinguished, but with a few games the colors in green will become true colors and their distinction almost perfect.
 +
 +To guess the key we have ten possible combinations, in each of which the computer will tell us if they are correctly placed or if they belong to the combination but are not in the right place.
 +
 +===== Listing =====
 +
 +   * **__Listing - MASTERES.BAS__**
 +
 +<file>
 +
 +100 OPTION RUN:PRINT CHR$(27)"0";
 +110 RANDOMIZE PEEK(64504!):GOSUB 1360:GOSUB 950:GOSUB 1800
 +120 PRINT TAB(3)"Juego N"uu$"m. (1/2/3): ";:GOSUB 130:GOSUB 1090:GOTO 150
 +130 md$=INKEY$:IF md$="" THEN 130 ELSE IF md$<>"1" AND md$<>"2" AND md$<>"3" THEN 130
 +140 PRINT md$;:FOR i=1 TO 100:NEXT:PRINT CHR$(27)+"f";:RETURN
 +150 PRINT FNloc$(26,7)"Pulse cualquier tecla"FNloc$(27,7)"para iniciar el juego"
 +160 WHILE INKEY$="":WEND:h=26:ey=1
 +170 FOR f=26 TO 27:PRINT FNloc$(f,7)STRING$(21,32):NEXT
 +180 '***** PREPARACION DE CLAVE *****
 +190 c=41:a$="RVANBZ":clave$="":p=6
 +200 IF md$="1" THEN 230
 +210 IF md$="3" THEN a$=a$+CHR$(32):p=7
 +220 FOR i=1 TO 4:clave$=clave$+MID$(a$,INT(RND*p+1),1):GOSUB 260:NEXT:GOTO 310
 +230 FOR i=1 TO 4
 +240 z=INT(RND*6+1):m$=MID$(a$,z,1):IF m$=CHR$(32) THEN 240
 +250 MID$(a$,z,1)=CHR$(32):clave$=clave$+m$:GOSUB 260:NEXT:GOTO 310
 +260 FOR z=1 TO INT(RND*10+5)
 +270 f=INT(RND*11):IF f MOD 2<>0 THEN f=f+1
 +280 f=f+192:PRINT FNloc$(4,c)CHR$(f)CHR$(f+1):OUT 248,11:OUT 248,12:FOR t=1 TO 50:NEXT
 +290 NEXT:PRINT FNloc$(4,c)it$CHR$(7):c=c+3:RETURN
 +300 '***** ENSAYO DEL JUGADOR *****
 +310 p=40:i=1:ensayo$=STRING$(4,32)
 +320 PRINT FNpton$(h,p)
 +330 a$=UPPER$(INPUT$(1)):a=ASC(a$)
 +340 IF a=6 THEN IF p=49 THEN 330 ELSE PRINT FNptof$(h,p):i=i+1:p=p+3:GOTO 320
 +350 IF a=1 THEN IF p=40 THEN 330 ELSE PRINT FNptof$(h,p):i=i-1:p=p-3:GOTO 320
 +360 IF a=13 THEN IF VAL(md$)<3 AND INSTR(ensayo$,CHR$(32))<>0 THEN 330 ELSE PRINT FNptof$(h,p):GOTO 470
 +370 IF a=32 THEN a$=CHR$(215)+CHR$(216):GOTO 450
 +380 IF a$="R" THEN a$=rj$:GOTO 450
 +390 IF a$="V" THEN a$=vd$:GOTO 450
 +400 IF a$="A" THEN a$=am$:GOTO 450
 +410 IF a$="N" THEN a$=ng$:GOTO 450
 +420 IF a$="B" THEN a$=bl$:GOTO 450
 +430 IF a$="Z" THEN a$=az$:GOTO 450
 +440 GOTO 330
 +450 PRINT FNloc$(h,p+1)a$:MID$(ensayo$,i,1)=CHR$(a):GOTO 330
 +460 '***** RESPUESTA ORDENADOR *****
 +470 p=33:resp$=STRING$(4,32)
 +480 FOR i=1 TO 4
 +490 IF MID$(clave$,i,1)=MID$(ensayo$,i,1) THEN MID$(resp$,i,1)="1"
 +500 NEXT
 +510 FOR i=1 TO 4:IF MID$(resp$,i,1)="1" THEN 540
 +520 FOR z=1 TO 4:IF MID$(clave$,i,1)=MID$(ensayo$,z,1) THEN 600
 +530 NEXT z
 +540 NEXT i
 +550 IF resp$=STRING$(4,"1") THEN PRINT FNloc$(h,34)STRING$(4,sn$):GOTO 630
 +560 IF resp$=STRING$(4,32) THEN 790 ELSE p=p+1
 +570 i=INT(RND*4+1):IF MID$(resp$,i,1)=CHR$(32) THEN 570
 +580 IF MID$(resp$,i,1)="0" THEN PRINT FNloc$(h,p)sb$ ELSE PRINT FNloc$(h,p)sn$
 +590 MID$(resp$,i,1)=CHR$(32):GOTO 560
 +600 IF MID$(resp$,z,1)<>CHR$(32) THEN 530
 +610 MID$(resp$,z,1)="0":GOTO 540
 +620 '***** RESULTADOS *****
 +630 a$="CLAVE DESCIFRADA":b$="Ha conseguido descifrar"
 +640 FOR i=1 TO 20:PRINT CHR$(7);:NEXT
 +650 PRINT FNloc$(12,6)a$FNloc$(14,6)b$FNloc$(15,6)"la clave."FNloc$(16,6)"Jugada n"CHR$(161)ey
 +660 GOSUB 830:GOSUB 810:p=41:FOR i=1 TO 4:a$=MID$(clave$,i,1)
 +670 IF a$="R" THEN b$=rj$
 +680 IF a$="V" THEN b$=vd$
 +690 IF a$="A" THEN b$=am$
 +700 IF a$="N" THEN b$=ng$
 +710 IF a$="Z" THEN b$=az$
 +720 IF a$="B" THEN b$=bl$
 +730 IF a$=CHR$(32) THEN b$=CHR$(215)+CHR$(216)
 +740 PRINT FNloc$(4,p)b$;CHR$(7):FOR z=1 TO 700:NEXT:p=p+3:NEXT
 +750 PRINT FNloc$(26,6)CHR$(27)"eOtra partida (S/N): ";
 +760 a$=UPPER$(INPUT$(1)):IF a$<>"S" AND a$<>"N" THEN 760
 +770 IF a$="N" THEN PRINT cls$:OPTION STOP:PRINT CHR$(27)"1":END
 +780 PRINT a$;FNloc$(27,6)"Juego N"uu$"m. (1/2/3): ";:GOSUB 130:GOSUB 920:GOSUB 1150:GOTO 150
 +790 IF h>8 THEN h=h-2:ey=ey+1:GOTO 310 ELSE h=0
 +800 a$="POSIBILIDADES AGOTADAS":b$="No consigui"+oo$+" descifrar":GOTO 640
 +810 PRINT FNloc$(20,6)"Pulse cualquier tecla"FNloc$(21,6)"para mostrar la clave"
 +820 WHILE INKEY$="":WEND:FOR f=20 TO 21:PRINT FNloc$(f,6)STRING$(21,32):NEXT:RETURN
 +830 IF ey<3 THEN PRINT FNloc$(17,6)"Ha habido SUERTE":RETURN ELSE PRINT FNloc$(17,6)"L"oo$"gica: ";:RESTORE 930
 +840 IF md$="3" THEN m=1:GOTO 860
 +850 IF md$="2" THEN m=2 ELSE m=3
 +860 FOR z=1 TO m:READ a$:NEXT
 +870 IF ey<6 THEN m=1
 +880 IF ey>5 AND ey<9 THEN m=2
 +890 IF ey>8 AND ey<11 THEN m=3
 +900 IF ey=10 AND h=0 THEN m=4
 +910 FOR z=1 TO m-1:READ a$:NEXT:PRINT a$::RETURN
 +920 PRINT FNpant$(6,6,22,23)cls$FNpant$(0,0,31,90):RETURN
 +930 DATA Exelente,"Muy buena",Buena,Regular,Mala,"Muy mala"
 +940 '****** INICIALIZACION VARIABLES *****
 +950 cls$=CHR$(27)+"E"+CHR$(27)++"H"
 +960 vi$=CHR$(27)+"p":vn$=CHR$(27)+"q"
 +970 DEF FNloc$(f,c)=CHR$(27)+"Y"+CHR$(f+32)+CHR$(c+32)
 +980 DEF FNpton$(x,y)=FNloc$(x,y)+CHR$(149)+FNloc$(x,y+3)+CHR$(149)
 +990 DEF FNptof$(x,y)=FNloc$(x,y)+CHR$(32)+FNloc$(x,y+3)+CHR$(32)
 +1000 DEF FN pant$(f,c,x,y)=CHR$(27)+"X"+CHR$(f+32)+CHR$(c+32)+CHR$(x+31)+CHR$(y+31)
 +1010 bl$=CHR$(192)+CHR$(193):ng$=CHR$(194)+CHR$(195)
 +1020 az$=CHR$(196)+CHR$(197):rj$=CHR$(198)+CHR$(199)
 +1030 am$=CHR$(200)+CHR$(201):vd$=CHR$(202)+CHR$(203)
 +1040 it$=CHR$(217)+CHR$(218):sb$=CHR$(204):sn$=CHR$(205)
 +1050 FOR i=1 TO 4:ag$=ag$+CHR$(32)+CHR$(215)+CHR$(216):NEXT:ag$=ag$+CHR$(32)
 +1060 aa$=CHR$(224):ee$=CHR$(225):ii$=CHR$(226):oo$=CHR$(227):uu$=CHR$(228)
 +1070 RETURN
 +1080 '***** DIBUJO DEL TABLERO *****
 +1090 PRINT cls$:f=1:c=4:m=80:h=30:GOSUB 1320
 +1100 PRINT FNloc$(0,5)" * M A S T E R   MI N D *"FNloc$(0,49)CHR$(164)" 1988 Gustavo Ernesto Garc"ii$"a P"ee$"rez"
 +1110 f=2:c=30:m=25:h=29:GOSUB 1320
 +1120 PRINT FNloc$(6,31)CHR$(206)CHR$(207)STRING$(21,154)CHR$(208)CHR$(209)
 +1130 FOR f=7 TO 27:PRINT FNloc$(f,31)CHR$(149)TAB(28)CHR$(149):NEXT
 +1140 PRINT FNloc$(28,31)CHR$(210)CHR$(211)STRING$(21,154)CHR$(212)CHR$(213)
 +1150 f=3:c=39:m=13:h=5:GOSUB 1320:PRINT FNloc$(4,40)ag$
 +1160 PRINT FNloc$(7,33)CHR$(150)STRING$(4,154)CHR$(156)CHR$(134)STRING$(13,138)CHR$(140):f=8
 +1170 PRINT FNloc$(f,33)CHR$(157)STRING$(4,214)CHR$(149)CHR$(149)ag$CHR$(151)
 +1180 IF f=26 THEN 1210 ELSE f=f+1
 +1190 PRINT FNloc$(f,33)CHR$(151)STRING$(4,154)CHR$(157)CHR$(135)STRING$(13,138)CHR$(141)
 +1200 f=f+1:GOTO 1170
 +1210 PRINT FNloc$(27,33)CHR$(147)STRING$(4,154)CHR$(153)CHR$(131)STRING$(13,138)CHR$(137)
 +1220 PRINT FNloc$(3,32)"MASTER"FNloc$(4,32)CHR$(214)"MIND"CHR$(214)FNloc$(5,31)CHR$(147)STRING$(6,154)CHR$(153)
 +1230 PRINT FNloc$(4,8)"Modalidad de juego:"FNloc$(4,62)"Clavijas de c"oo$"digo:"
 +1240 PRINT FNloc$(6,11)"Juego N"uu$"m. "md$FNloc$(6,66)bl$"... "vi$"B"vn$"lanca"
 +1250 IF md$="1" THEN PRINT FNloc$(8,11)"360 claves":GOTO 1280
 +1260 IF md$="2" THEN PRINT FNloc$(8,11)"1296 claves":GOTO 1280
 +1270 PRINT FNloc$(8,11)"2401 claves"
 +1280 PRINT FNloc$(8,66)am$"... "vi$"A"vn$"marilla"FNloc$(10,66)vd$"... "vi$"V"vn$"erde"FNloc$(12,66)rj$"... "vi$"R"vn$"oja"
 +1290 PRINT FNloc$(14,66)az$"... a"vi$"Z"vn$"ul"FNloc$(16,66)ng$"... "vi$"N"vn$"egra"FNloc$(19,59)"ESPACIO... extrae clavija"
 +1300 PRINT FNloc$(21,59)"RETURN... entrega c"oo$"digo"FNloc$(23,59)"TECLAS de CURSOR..."
 +1310 f=25:c=64:m=13:h=27:GOSUB 1320:PRINT FNloc$(26,67)CHR$(27)CHR$(11)CHR$(149)CHR$(215)CHR$(216)CHR$(149)CHR$(27)CHR$(12):RETURN
 +1320 PRINT FN loc$(f,c)CHR$(150)STRING$(m,154)CHR$(156)
 +1330 FOR i=f+1 TO h-1:PRINT FNloc$(i,c)CHR$(149)FNloc$(i,c+m+1)CHR$(149):NEXT
 +1340 PRINT FNloc$(i,c)CHR$(147)STRING$(m,154)CHR$(153):RETURN
 +1350 '***** DISE\O DE FICHAS *****
 +1360 MEMORY &HEA5F:RESTORE 1380
 +1370 FOR i=0 TO 53:READ z:POKE &HEA60+i,z:NEXT
 +1380 DATA 42,1,0,17,87,0,237,90
 +1390 DATA 34,123,234,33,160,234,1,128
 +1400 DATA 234,205,122,234,233,0,0,201
 +1410 DATA 0,0,195,0,0,201,0,0
 +1420 DATA 126,35,229,111,38,0,41,41
 +1430 DATA 41,17,0,184,25,229,209,225
 +1440 DATA 1,8,0,237,176,201
 +1450 rutina=&HEA60:codigo=&HEAA0
 +1460 READ p:IF p=0 THEN RETURN
 +1470 FOR i=1 TO 8:READ z:POKE codigo+i,z:NEXT
 +1480 POKE codigo,p
 +1490 CALL rutina
 +1500 GOTO 1460
 +1510 DATA 192,15,63,127,255,255,127,63,15
 +1520 DATA 193,240,252,254,255,255,254,252,240
 +1530 DATA 194,15,56,96,192,192,96,56,15
 +1540 DATA 195,240,28,6,3,3,6,28,240
 +1550 DATA 196,15,48,68,160,136,64,49,15
 +1560 DATA 197,240,76,10,129,17,66,12,240
 +1570 DATA 198,15,49,72,196,162,81,56,15
 +1580 DATA 199,240,28,138,69,35,18,140,240
 +1590 DATA 200,15,59,108,211,204,115,60,15
 +1600 DATA 201,240,60,206,51,203,54,220,240
 +1610 DATA 202,15,53,106,213,170,85,42,15
 +1620 DATA 203,240,92,170,85,171,86,172,240
 +1630 DATA 204,0,0,124,254,254,124,0,0
 +1640 DATA 205,0,0,124,198,198,124,0,0
 +1650 DATA 206,15,56,96,192,192,96,56,24
 +1660 DATA 207,240,28,6,3,3,0,0,0
 +1670 DATA 208,15,56,96,192,192,0,0,0
 +1680 DATA 209,240,28,6,3,3,6,28,24
 +1690 DATA 210,24,56,96,192,192,96,56,15
 +1700 DATA 211,0,0,0,3,3,6,28,240
 +1710 DATA 212,0,0,0,192,192,96,56,15
 +1720 DATA 213,24,28,6,3,3,6,28,240
 +1730 DATA 214,0,0,0,56,56,0,0,0
 +1740 DATA 215,0,0,0,3,3,0,0,0
 +1750 DATA 216,0,0,0,192,192,0,0,0
 +1760 DATA 217,15,56,99,198,192,96,56,15
 +1770 DATA 218,240,28,198,99,195,198,28,240
 +1780 DATA 0
 +1790 REM ******* INSTRUCCIONES *******
 +1800 PRINT cls$"MASTER MIND es un juego de l"oo$"gica y estrategia en el que usted debe tratar de descubrir"
 +1810 PRINT TAB(16)"una clave secreta en un m"aa$"ximo de diez jugadas."
 +1820 PRINT "El ordenador pondr"aa$" en secreto cuatro de las seis clavijas de c"oo$"digo. Usted deber"aa$" tratar"
 +1830 PRINT "de repetir las clavijas de los mismos colores y en las posiciones exactas de la clave se-"
 +1840 PRINT "creta. Cada vez que coloque una fila de clavijas de c"oo$"digo, se le proporcionar"aa$" informa-"
 +1850 PRINT "ci"oo$"n colocando "CHR$(27)"raleatoriamente"CHR$(27)"u -en el lugar destinado a ello-, las clavijas informativas"
 +1860 PRINT "siguientes:":PRINT
 +1870 PRINT TAB(9)sn$" Se colocar"aa$" una clavija informativa negra por cada clavija de c"oo$"digo"
 +1880 PRINT TAB(11)"que usted acierte en color y lugar."
 +1890 PRINT TAB(9)sb$" Se colocar"aa$" una clavija informativa blanca por cada clavija de c"oo$"digo"
 +1900 PRINT TAB(11)"acertada en color pero fuera de lugar."
 +1910 PRINT TAB(9)CHR$(214)" Se dejar"aa$" un agujero de clavija informativa vac"ii$"o por cada clavija de"
 +1920 PRINT TAB(11)"c"oo$"digo que no forme parte de la clave secreta.":PRINT
 +1930 PRINT "- Juego N"uu$"m. 1 (360 claves posibles)"
 +1940 PRINT "  En esta modalidad la clave secreta estar"aa$" formada por cuatro de las seis clavijas sin"
 +1950 PRINT "  que se repita ninguna de ellas. Es el nivel de juego m"aa$"s bajo.":PRINT
 +1960 PRINT "- Juego N"uu$"m. 2 (1.296 claves posibles)"
 +1970 PRINT "  La clave secreta que usted debe tratar de descubrir estar"aa$" formada por cuatro clavijas"
 +1980 PRINT "  que pueden, o no, estar repetidas. Esta modalidad supone un nivel m"aa$"s avanzado de juego.":PRINT
 +1990 PRINT "- Juego N"uu$"m. 3 (2.401 claves posibles)"
 +2000 PRINT "  Esta modalidad es igual que la segunda, pero aqu"ii$" se pueden usar agujeros vac"ii$"os repre-"
 +2010 PRINT "  sentando otro color de clavija. Este juego equivale pues a utilizar clavijas de c"oo$"digo"
 +2020 PRINT "  de siete colores que pueden, o no, estar repetidas. Habr"aa$" que imaginar que cada agujero"
 +2030 PRINT "  vac"ii$"o constituye otro color de clavija. Es la modalidad de m"aa$"s alto nivel.":PRINT:RETURN
 +
 +</file>
 +
 +===== Controls =====
 +
 +         B = WHITE
 +         A = YELLOW
 +         G = GREEN
 +         R = RED
 +         Z = BLUE
 +         N = BLACK
 +         ← = LEFT
 +         → = RIGHT
 +     SPACE = REMOVE TOKEN
 +    RETURN = DELIVERY CODE
 +        
 +
 +===== Loading the program =====
 +
 +   1.- Insert the CP/M disc on side 2
 +   2.- Write BASIC and wait for it to load
 +   3.- Remove the CP/M disk and insert the disk containing the Master-Mind game
 +   4.- Type run "MASTERES" and press the "ENTER" key
 +
 +===== Extras =====
 +
 +   * Listing of the program in a magazine of great circulation of the time
 +
 +{{:otros:Master_Mind_sp_programa_01.jpg?170}} {{:otros:Master_Mind_sp_programa_02.jpg?170}} {{:otros:Master_Mind_sp_programa_03.jpg?170}} {{:otros:Master_Mind_sp_programa_04.jpg?170}}
 +
 +
 +===== Download =====
 +
 +  * {{:otros:Master_Mind_sp.zip|Master-Mind }}(game in dsk format, compressed with zip)
  
en/master_mind_espanol.txt · Last modified: 2022/06/30 13:33 by jevicac