User Tools

Site Tools


Translations of this page:



en:aranas

ARAÑAS

Info

Author ????
Computer Amstrad PCW 8256 / 8512 / 9512
Year ????
Gender Arcade
Controls Keyboard
Languages Spanish
State Preserved

Screenshots

Description

Entertaining and fun game where we will have to demonstrate our agility and speed when it comes to killing some spiders that reproduce all over the screen. We'll have to be quick to get the highest score, but we'll have to be somewhat cunning and control the DDT fumigator that we're running out of.

Due to the influence of Halley's comet, the spiders in my house reproduce in an amazing quantity, so it is necessary to exterminate them with -DDT-, for which we use the fumigator.

Listing

  • Listing - ARANAS.BAS
1 esc$=CHR$(27):CL$=esc$+"E"+esc$+"H"
2 DEF FNLOC$(f,c)=esc$+"Y"+CHR$(32+c)+CHR$(32+f)
3 iv$=esc$+"p":tv$=esc$+"q":acs$=CHR$(27)+CHR$(114):des$=CHR$(27)+CHR$(117)
4 DEF FN fin$(f,c,p,a)=esc$+"X"+CHR$(32+f)+CHR$(32+c)+CHR$(31+p)+CHR$(31+a)
5 PRINT CHR$(27)+"f"
10 REM *******************************
20 REM **                           **
30 REM **          ARAÑAS           **
40 REM **            BY             **
50 REM **  ???????????????????????  **
60 REM **                           **
70 REM *******************************
80 DIM t(90):sc=100
90 REM **************************************************
100 GOSUB 5010:GOSUB 860
110 REM definicion de nuevas teclas, por falta de instrucciones desisto y pongo unas que me invento
130 mu=100
140 ' ? fn loc$(12,6)+"f"
150 x=46:vida=1:d=100
160 REM ****************** MOVIMIENTO DE LAS ARA\AS *************************
230 WHILE vida
240 cual=INT(RND*mu)+27:IF cual>63 OR cual= xd THEN GOTO 300
245 IF cual MOD 2 <>0 THEN cual=cual-1
250 t(cual)=t(cual)+3
260 PRINT FN loc$(cual,t(cual)-1)+CHR$(149):PRINT FN loc$(cual,t(cual))+CHR$(149):PRINT FNloc$(cual,t(cual)+1)+CHR$(149):PRINT FN loc$(cual,t(cual)+2)+"%"
270 IF t(cual)>23 THEN vida=0
280 REM ****************** MOVIMIENTO DEL FULMIGADOR ************************
290 PRINT FN loc$(x,26);"0":PRINT FN loc$(x,27);"4"
300 a$=""
301 a$=INKEY$
310 IF a$="Z" OR a$="z" THEN x=x-2:GOSUB 470:GOSUB 3000
320 IF a$="X" OR a$="x" THEN x=x+2:GOSUB 470:GOSUB 4000
330 IF sw=0 THEN IF a$="f" OR a$="F" THEN sw=1:xd=x:yd=24:PRINT CHR$(7)
340 IF sw=1 THEN GOSUB 590:GOSUB 500:sw=0:GOSUB 490:GOSUB 5000:t(xd)=0:mu=mu-0.5:d=d-1:PRINT FN loc$(75,24);" ";INT(d);" ":IF d=0 THEN GOSUB 830
350 WEND
360 GOSUB 520
370 REM ****************** PUNTUACION **********************
380 IF pp>sc THEN sc=pp:PRINT FN loc$(77,14)+CHR$(7);INT(sc)
390 pp=0
400 PRINT TAB (30)"OTRA PARTIDA S/N"
410 d$=INKEY$:d$=UPPER$(d$)
420 IF d$="S" THEN PRINT cl$:CLEAR:GOTO 1
430 IF d$="N" THEN END ELSE 410
470 IF x<26 THEN x=26
480 IF x>62 THEN x=62
490 PRINT FN loc$(x,26)+"0":PRINT FN loc$(x,27)+"4":RETURN
500 FOR i=24 TO 2 STEP -1:PRINT FN loc$(xd,i)+"'":PRINT FN loc$(xd,i+1)+" ":NEXT i:PRINT FN loc$(xd,2)+" ":RETURN
520 FOR p=1 TO 3:PRINT FN loc$(x,26)+"'":NEXT p:PRINT FN loc$(x,26)+"-":GOSUB 550:FOR x=cual TO 12 STEP-1:PRINT FN loc$(x,28)+" % ":FOR c=0 TO 400:NEXT c
530 GOTO 560
540 GOSUB 560
550 PRINT FN loc$(cual,26)+CHR$(145):PRINT FN loc$(cual,27)+CHR$(145):PRINT FN loc$(cual,28)+CHR$(145):RETURN
560 NEXT x:FOR y=28 TO 7 STEP -1:PRINT FN loc$(10,y);" % ":PRINT FN loc$(10,y+1);"   ":PRINT FN loc$(12,28)+" ":NEXT y:PRINT FN loc$(12,7)+" "
570 PRINT FN loc$(4,3)+"FIN":PRINT FN LOC$(2,5)+"PARTIDA":RETURN
590 IF yd>23 THEN RETURN ELSE IF yd=3 THEN PRINT CHR$(7):RETURN ELSE RETURN
610 FOR r=13 TO 23:PRINT FN loc$(31,r)+STRING$(29," "):NEXT r
611 RETURN
620 RETURN
830 PRINT FN loc$(25,28)+"RENOVACION DEL DDT":FOR l=0 TO 100:PRINT FN loc$(75,24)+" ";l;" ":NEXT l:PRINT FN loc$(25,28)+" ":RETURN
860 PRINT cl$:GOSUB 1000
870 PRINT FN loc$(31,14)+STRING$(27," ")
880 REM INSTRUCCIONES
890 PRINT FN loc$(31,14)+"POR LA INFLUENCIA DEL COMETA"
900 PRINT FN loc$(31,15)+"HALLEY LAS ARA\AS DE MI CASA"
910 PRINT FN loc$(31,16)+"SE REPRODUCEN  EN  ASOMBROSA"
920 PRINT FN loc$(31,17)+"CANTIDAD, POR LO QUE ES  NE-"
930 PRINT FN loc$(31,18)+"CESARIO  EXTERMINARLAS   CON"
940 PRINT FN loc$(31,19)+"DDT.  PARA  LO  CUAL HACEMOS"
950 PRINT FN loc$(31,20)+"USO DE UN SPRAY QUE SE MUEVE"
960 PRINT FN loc$(31,21)+"CON <X> Y <Z>, PARA PULVERI-"
970 PRINT FN loc$(31,22)+"ZAR SPRAY PULSA <F>..."
975 a$=""
980 WHILE a$<>" ":a$=INKEY$:WEND
990 GOSUB 610
995 RETURN
1000 PRINT FNloc$(0,0)+STRING$(90,"&")+FN loc$(0,29)+STRING$(90,"&");
1010 FOR r=1 TO 28
1020 PRINT FN loc$(0,r)+STRING$(25,"&")+FN loc$(65,r)+STRING$(25,"&");
1030 NEXT r:PRINT des$
1040 PRINT FN loc$(70,6)+tv$+"    ARA\AS    "
1050 FOR r=1 TO 7
1060 PRINT FN LOC$(70,r+8)+"              "
1070 NEXT r
1080 PRINT FN loc$(6,8)+" Z: Izquierda "
1090 PRINT FN loc$(6,10)+" X: Derecha   "
1100 PRINT FN loc$(6,12)+" F:    DDT    "
1110 PRINT FN loc$(75,10)+"PUNTOS";:PRINT FN loc$(75,13)+"RECORD"
1120 PRINT FN loc$(75,22)+" DDT "
1130 PRINT FN LOC$(31,14)+"PULSA ESPACIO PARA COMENZAR"
1140 WHILE a$<>" ":a$=INKEY$:WEND
1150 RETURN
3000 IF x=26 THEN l=24 ELSE l=x
3001 PRINT FN loc$(l+2,26)+" ":PRINT FN loc$(l+2,27)+" ":RETURN
4000 IF x=62 THEN l=64 ELSE l=x
4001 PRINT FN loc$(l-2,26)+" ":PRINT FN loc$(l-2,27)+" ":RETURN
5000 IF t(xd)<>0 THEN pp=pp+5:PRINT FN loc$(75,11);pp:RETURN ELSE RETURN
5010 REM *********************** REDEFINICION DE GRAFICOS *****************************
5030 REM
5040 REM
5050 MEMORY &HBFFE
5060 FOR N=&HC070 TO &HC098
5070 READ D8
5080 POKE N,D8
5090 NEXT N
5100 P9=0:FOR n=&HC070 TO &HC098:p9=p9+PEEK(N):NEXT n
5110 IF P9 <> 5540 THEN ERROR 51
5120 REM
5130 REM ********************** DATAS DEL PROGRAMA ***********************************
5140 REM
5150 DATA 243,62,129,211,241,62,130,211,242,175,95,103
5160 DATA 22,184,58,153,192,111,41,41,41,25,17,154
5170 DATA 192,235,1,8,0,237,176,62,133,211,241,62
5180 DATA 134,211,242,251,201
5190 REM ********************** CARGAR CARACTERES GRAFICOS ***************************
5200 OPEN "R",1,"ARANAS.CAR",1:C=&HC070
5210 FIELD #1,1 AS Z$
5220 FOR n=164 TO 255:POKE &HC099,n
5230 FOR n2=1 TO 8
5240 GET #1:POKE &HC099+n2,ASC(Z$)
5250 NEXT n2:CALL c:NEXT:CLOSE:RETURN

Controls

       Z = LEFT
       X = RIGHT
       F = DDT

Loading the program

 1.- Insert the CP/M disc on side 2
 2.- Write BASIC and wait for it to load
 3.- Remove the CP/M disk and insert the disk containing the game Arañas
 4.- Type run "ARANAS" and press the "ENTER" key

Download

  • Arañas (game in dsk format, compressed with zip)

Video

en/aranas.txt · Last modified: 2022/06/30 10:09 by jevicac